File talk:Coffee Bean Structure.png

This image was in Commons:Requests for Translation as follows:

• Image: ja:画像:Coffee Bean.png
• Worth doing because: Highly informative picture with no equivelent in English (or any other language)
• Originally requested by: Oldak Quill 22:39, 11 Jan 2005 (UTC)

POV-Ray source file

//coffee_bean.pov for POV-Ray3.6
//by Y tambe
//You can use this source file under either GFDL or CC-by-sa (dual license)
//You can use the images you render as free.

camera {
	perspective
	angle 45
	location <0.0, 0.0, 4>
	look_at <0.0, 0.0, 0.0>
	rotate -30*x
}

//lights
light_source { <200, 200, 200> rgb <1, 1, 1> }
light_source { <-100, -100, 100> rgb <.3, .3, .3> shadowless}
light_source { <-100, 100, -100> rgb <.2, .2, .2> shadowless}


#declare T_Red_Cherry_Skin= texture {
	pigment{ color <0.83, 0.08, 0.02>}
	finish{phong 0.5 phong_size  10}
	//normal{bozo 1 scale 0.02}
}
	
#declare T_Cherry = texture {
	pigment{ color <1.0, 0.65, 0.40>}
	finish{ ambient 0.4 diffuse 0.6
	crand 0.1
	}	
}

#declare T_Pectin = texture {
	pigment{ color rgbt <1, 1, 0.8, 0.6>}
	finish{ ambient 0.4 diffuse 0.6	}	
	normal{bozo 3 scale 0.05}
}
	
#declare T_Bean = texture {
	pigment{ color <0.8, 0.95, 0.60>}
	finish{ ambient 0.4 diffuse 0.6}	
}

#declare T_Partiment = texture {
	pigment{ color <0.9, 0.95, 0.60>}
	finish{ ambient 0.4 diffuse 0.6}	
	//normal{bozo 1 scale 0.02}
}

#declare T_SilverSkin = texture {
	pigment{ color <1, 0.9, 0.50>}
	finish{ ambient 0.3 diffuse 0.7
	crand 0.2
	}
}

#declare coffee_cherry =
union{
	difference{
		sphere{0,1 scale <1,1,1.1> rotate 20*y translate -0.05*x}
		plane{ -x, 0}
	}
	difference{
		sphere{0,1 scale <1,1,1.1> rotate -20*y translate 0.05*x}
		plane{ x, 0}
	}
	scale <1,1.1,0.85>
	texture{T_Red_Cherry_Skin}
}

#declare halfcut_cherry =
difference{
	object{coffee_cherry}
	plane{ -y, -0.1
		texture{T_Cherry}	
	}
}



#declare coffee_bean_base =
merge{
	difference{
		sphere{0. 1 scale <1,1.2,1>}
		plane{ -z,0.01}
	}
	difference{
		sphere{0. 1 scale <1,1.2,0.2>}
		plane{ z,-0.01}
	}
}



#declare coffee_bean =
merge{
	difference{
		object{coffee_bean_base}
		object{coffee_bean_base translate -0.2*z scale <0.7,0.9,0.7> rotate 20*y translate 0.2*z}
	}
	intersection{
		object{coffee_bean_base translate -0.2*z scale <0.65,0.9001,0.55> rotate 20*y translate 0.2*z translate <-0.1,0,-0.05>}
		object{coffee_bean_base}
		translate <-0.0001,0,0>
	}
	texture{T_Bean}

}

#declare coffee_partiment =
difference{//partiment
	object{coffee_bean_base scale 1.2}
	object{coffee_bean_base scale 1.1}
	texture{T_Partiment}
}

#declare coffee_silver_skin =
difference{//SilverSkin
	object{coffee_bean_base scale 1.1}
	texture{T_SilverSkin}
}


#declare halfcut_bean =
merge{
	difference{
		object{coffee_partiment}
		plane{ -y, -0.03-0.2		texture{T_Partiment}		}
	}
	difference{
		object{coffee_silver_skin}
		plane{ -y,-0.02-0.2		texture{T_SilverSkin}		}
	}
	difference{
		object{coffee_bean}
		plane{ -y,-0.04-0.2		texture{T_Bean}		}
	}
}


#declare structures =
merge{

	object{halfcut_cherry}

	difference{
		object{coffee_bean_base scale 1.2*0.65 rotate 90*y translate -0.15*x no_shadow texture{T_Pectin} }
		plane{ -y,-0.03-0.08 no_shadow texture{T_Pectin} }
	}

	difference{
		object{coffee_bean_base scale 1.2*0.65 rotate -90*y translate 0.15*x no_shadow texture{T_Pectin} }
		plane{ -y,-0.03-0.08 no_shadow texture{T_Pectin} }
	}

	object{halfcut_bean scale 0.6 rotate 90*y translate -0.15*x no_shadow}
	object{coffee_partiment scale 0.6 rotate -90*y translate 0.15*x no_shadow}

	rotate 170*y
}


object{structures scale <1,1.1,1>}